DBIx::Class::DB - (DEPRECATED) classdata schema component

package DBIx::Class::DB;

use strict;
use warnings;

use base qw/DBIx::Class/;
use DBIx::Class::Schema;
use DBIx::Class::Storage::DBI;
use DBIx::Class::ClassResolver::PassThrough;
use DBI;
use Scalar::Util;

unless ($INC{"DBIx/Class/CDBICompat.pm"}) {
  warn "IMPORTANT: DBIx::Class::DB is DEPRECATED AND *WILL* BE REMOVED. DO NOT USE.\n";
}

__PACKAGE__->load_components(qw/ResultSetProxy/);

{
    no warnings 'once';
    *dbi_commit = \&txn_commit;
    *dbi_rollback = \&txn_rollback;
}

sub storage { shift->schema_instance(@_)->storage; }

__PACKAGE__->mk_classdata('class_resolver' =>
                          'DBIx::Class::ClassResolver::PassThrough');

sub connection {
  my ($class, @info) = @_;
  $class->setup_schema_instance unless $class->can('schema_instance');
  $class->schema_instance->connection(@info);
}

sub setup_schema_instance {
  my $class = shift;
  my $schema = {};
  bless $schema, 'DBIx::Class::Schema';
  $class->mk_classdata('schema_instance' => $schema);
}

sub txn_begin { shift->schema_instance->txn_begin(@_); }

sub txn_commit { shift->schema_instance->txn_commit(@_); }

sub txn_rollback { shift->schema_instance->txn_rollback(@_); }

sub txn_do { shift->schema_instance->txn_do(@_); }

{
  my $warn;

  sub resolve_class {
    warn "resolve_class deprecated as of 0.04999_02" unless $warn++;
    return shift->class_resolver->class(@_);
  }
}

sub resultset_instance {
  $_[0]->result_source_instance->resultset
}

__PACKAGE__->mk_classdata('_result_source_instance' => []);

# Yep. this is horrific. Basically what's happening here is that
# (with good reason) DBIx::Class::Schema copies the result source for
# registration. Because we have a retarded setup order forced on us we need
# to actually make our ->result_source_instance -be- the source used, and we
# need to get the source name and schema into ourselves. So this makes it
# happen.

sub _maybe_attach_source_to_schema {
  my ($class, $source) = @_;
  if (my $meth = $class->can('schema_instance')) {
    if (my $schema = $class->$meth) {
      $schema->register_class($class, $class);
      my $new_source = $schema->source($class);
      %$source = %$new_source;
      $schema->source_registrations->{$class} = $source;
    }
  }
}

sub result_source_instance {
  my $class = shift;
  $class = ref $class || $class;

  if (@_) {
    my $source = $_[0];
    $class->_result_source_instance([$source, $class]);
    $class->_maybe_attach_source_to_schema($source);
    return $source;
  }

  my($source, $result_class) = @{$class->_result_source_instance};
  return unless Scalar::Util::blessed($source);

  if ($result_class ne $class) {  # new class
    # Give this new class its own source and register it.
    $source = $source->new({ 
        %$source, 
        source_name  => $class,
        result_class => $class
    } );
    $class->_result_source_instance([$source, $class]);
    $class->_maybe_attach_source_to_schema($source);
  }
  return $source;
}

1;