DBIx::Class::ResultClass::HashRefInflator - Get raw hashrefs from a resultset

DBIx-Class documentation Contained in the DBIx-Class distribution.

Index

Code Index:

NAME

Top

DBIx::Class::ResultClass::HashRefInflator - Get raw hashrefs from a resultset

SYNOPSIS

Top

 use DBIx::Class::ResultClass::HashRefInflator;

 my $rs = $schema->resultset('CD');
 $rs->result_class('DBIx::Class::ResultClass::HashRefInflator');
 while (my $hashref = $rs->next) {
   ...
 }

  OR as an attribute:

 my $rs = $schema->resultset('CD')->search({}, {
   result_class => 'DBIx::Class::ResultClass::HashRefInflator',
 });
 while (my $hashref = $rs->next) {
   ...
 }

DESCRIPTION

Top

DBIx::Class is faster than older ORMs like Class::DBI but it still isn't designed primarily for speed. Sometimes you need to quickly retrieve the data from a massive resultset, while skipping the creation of fancy row objects. Specifying this class as a result_class for a resultset will change $rs->next to return a plain data hash-ref (or a list of such hash-refs if $rs->all is used).

There are two ways of applying this class to a resultset:

METHODS

Top

inflate_result

Inflates the result and prefetched data into a hash-ref (invoked by DBIx::Class::ResultSet)

CAVEATS

Top

DBIx-Class documentation Contained in the DBIx-Class distribution. 
package DBIx::Class::ResultClass::HashRefInflator;

use strict;
use warnings;


##############
# NOTE
#
# Generally people use this to gain as much speed as possible. If a new &mk_hash is
# implemented, it should be benchmarked using the maint/benchmark_hashrefinflator.pl
# script (in addition to passing all tests of course :). Additional instructions are
# provided in the script itself.
#

# This coderef is a simple recursive function
# Arguments: ($me, $prefetch, $is_root) from inflate_result() below
my $mk_hash;
$mk_hash = sub {
    if (ref $_[0] eq 'ARRAY') {     # multi relationship
        return [ map { $mk_hash->(@$_) || () } (@_) ];
    }
    else {
        my $hash = {
            # the main hash could be an undef if we are processing a skipped-over join
            $_[0] ? %{$_[0]} : (),

            # the second arg is a hash of arrays for each prefetched relation
            map
                { $_ => $mk_hash->( @{$_[1]->{$_}} ) }
                ( $_[1] ? (keys %{$_[1]}) : () )
        };

        # if there is at least one defined column *OR* we are at the root of
        # the resultset - consider the result real (and not an emtpy has_many
        # rel containing one empty hashref)
        # an empty arrayref is an empty multi-sub-prefetch - don't consider
        # those either
        return $hash if $_[2];

        for (values %$hash) {
            if (ref $_ eq 'ARRAY') {
              return $hash if @$_;
            }
            elsif (defined $_) {
              return $hash;
            }
        }

        return undef;
    }
};


##################################################################################
# inflate_result is invoked as:
# HRI->inflate_result ($resultsource_instance, $main_data_hashref, $prefetch_data_hashref)
sub inflate_result {
    return $mk_hash->($_[2], $_[3], 'is_root');

}



1;