DBIx::Class::Storage::DBI::ODBC::Microsoft_SQL_Server - Support specific

DBIx-Class documentation Contained in the DBIx-Class distribution.

Index

Code Index:

NAME

Top

DBIx::Class::Storage::DBI::ODBC::Microsoft_SQL_Server - Support specific to Microsoft SQL Server over ODBC

DESCRIPTION

Top

This class implements support specific to Microsoft SQL Server over ODBC. It is loaded automatically by by DBIx::Class::Storage::DBI::ODBC when it detects a MSSQL back-end.

Most of the functionality is provided from the superclass DBIx::Class::Storage::DBI::MSSQL.

USAGE NOTES

Top

Basic Linux Setup (Debian)

  sudo aptitude install tdsodbc libdbd-odbc-perl unixodbc

In case it is not already there put the following in /etc/odbcinst.ini:

  [FreeTDS]
  Description = FreeTDS
  Driver      = /usr/lib/odbc/libtdsodbc.so
  Setup       = /usr/lib/odbc/libtdsS.so
  UsageCount  = 1

Set your $dsn in connect_info as follows:

  dbi:ODBC:server=<my.host.name>;port=1433;driver=FreeTDS;tds_version=8.0

If you use the EasySoft driver (http://www.easysoft.com):

  dbi:ODBC:server=<my.host.name>;port=1433;driver=Easysoft ODBC-SQL Server

Basic Windows Setup

Use the following $dsn for the Microsoft ODBC driver:

  dbi:ODBC:driver={SQL Server};server=SERVER\SQL_SERVER_INSTANCE_NAME

And for the Native Client:

  dbi:ODBC:driver={SQL Server Native Client 10.0};server=SERVER\SQL_SERVER_INSTANCE_NAME

Go into Control Panel -> System and Security -> Administrative Tools -> Data Sources (ODBC) to check driver names and to set up data sources.

Use System DSNs, not User DSNs if you want to use DSNs.

If you set up a DSN, use the following $dsn for connect_info:

  dbi:ODBC:dsn=MY_DSN

MULTIPLE ACTIVE STATEMENTS

Top

The following options are alternative ways to enable concurrent executing statement support. Each has its own advantages and drawbacks and works on different platforms. Read each section carefully.

In order of preference, they are:

* mars
* dynamic_cursors
* server_cursors

METHODS

Top

connect_call_use_mars

Use as:

  on_connect_call => 'use_mars'

in your connection info, or alternatively specify it directly:

  Your::Schema->connect (
    $original_dsn . '; MARS_Connection=Yes',
    $user,
    $pass,
    \%attrs,
  )

Use to enable a feature of SQL Server 2005 and later, "Multiple Active Result Sets". See Does DBD::ODBC support Multiple Active Statements? in DBD::ODBC::FAQ for more information.

This does not work on FreeTDS drivers at the time of this writing, and only works with the Native Client, later versions of the Windows MS ODBC driver, and the Easysoft driver.

connect_call_use_dynamic_cursors

Use as:

  on_connect_call => 'use_dynamic_cursors'

Which will add odbc_cursortype => 2 to your DBI connection attributes, or alternatively specify the necessary flag directly:

  Your::Schema->connect (@dsn, { ... odbc_cursortype => 2 })

See odbc_cursortype in DBD::ODBC for more information.

If you're using FreeTDS, tds_version must be set to at least 8.0.

This will not work with CODE ref connect_info's.

WARNING: on FreeTDS (and maybe some other drivers) this will break SCOPE_IDENTITY(), and SELECT @@IDENTITY will be used instead, which on SQL Server 2005 and later will return erroneous results on tables which have an on insert trigger that inserts into another table with an IDENTITY column.

WARNING: on FreeTDS, changes made in one statement (e.g. an insert) may not be visible from a following statement (e.g. a select.)

connect_call_use_server_cursors

Use as:

  on_connect_call => 'use_server_cursors'

May allow multiple active select statements. See odbc_SQL_ROWSET_SIZE in DBD::ODBC for more information.

Takes an optional parameter for the value to set the attribute to, default is 2.

WARNING: this does not work on all versions of SQL Server, and may lock up your database!

At the time of writing, this option only works on Microsoft's Windows drivers, later versions of the ODBC driver and the Native Client driver.

using_freetds

Tries to determine, to the best of our ability, whether or not you are using the FreeTDS driver with DBD::ODBC.

AUTHOR

Top

See AUTHOR in DBIx::Class and CONTRIBUTORS in DBIx::Class.

LICENSE

Top

You may distribute this code under the same terms as Perl itself.

DBIx-Class documentation Contained in the DBIx-Class distribution. 
package DBIx::Class::Storage::DBI::ODBC::Microsoft_SQL_Server;
use strict;
use warnings;

use base qw/DBIx::Class::Storage::DBI::MSSQL/;
use mro 'c3';
use Scalar::Util 'reftype';
use Try::Tiny;
use DBIx::Class::Carp;
use namespace::clean;

__PACKAGE__->mk_group_accessors(simple => qw/
  _using_dynamic_cursors
/);


sub connect_call_use_mars {
  my $self = shift;

  my $dsn = $self->_dbi_connect_info->[0];

  if (ref($dsn) eq 'CODE') {
    $self->throw_exception('cannot change the DBI DSN on a CODE ref connect_info');
  }

  if ($dsn !~ /MARS_Connection=/) {
    if ($self->using_freetds) {
      $self->throw_exception('FreeTDS does not support MARS at the time of '
                            .'writing.');
    }

    if (exists $self->_server_info->{normalized_dbms_version} &&
               $self->_server_info->{normalized_dbms_version} < 9) {
      $self->throw_exception('SQL Server 2005 or later required to use MARS.');
    }

    if (my ($data_source) = $dsn =~ /^dbi:ODBC:([\w-]+)\z/i) { # prefix with DSN
      warn "Bare DSN in ODBC connect string, rewriting as 'dsn=$data_source'"
          ." for MARS\n";
      $dsn = "dbi:ODBC:dsn=$data_source";
    }

    $self->_dbi_connect_info->[0] = "$dsn;MARS_Connection=Yes";
    $self->disconnect;
    $self->ensure_connected;
  }
}

sub connect_call_use_MARS {
  carp "'connect_call_use_MARS' has been deprecated, use "
      ."'connect_call_use_mars' instead.";
  shift->connect_call_use_mars(@_)
}


sub connect_call_use_dynamic_cursors {
  my $self = shift;

  if (($self->_dbic_connect_attributes->{odbc_cursortype} || 0) < 2) {

    my $dbi_inf = $self->_dbi_connect_info;

    $self->throw_exception ('Cannot set DBI attributes on a CODE ref connect_info')
      if ref($dbi_inf->[0]) eq 'CODE';

    # reenter connection information with the attribute re-set
    $dbi_inf->[3] = {} if @$dbi_inf <= 3;
    $dbi_inf->[3]{odbc_cursortype} = 2;

    $self->_dbi_connect_info($dbi_inf);

    $self->disconnect; # resetting dbi attrs, so have to reconnect
    $self->ensure_connected;
  }
}

sub _run_connection_actions {
  my $self = shift;

  # keep the dynamic_cursors_support and driver-state in sync
  # on every reconnect
  my $use_dyncursors = ($self->_dbic_connect_attributes->{odbc_cursortype} || 0) > 1;
  if (
    $use_dyncursors
      xor
    !!$self->_using_dynamic_cursors
  ) {
    if ($use_dyncursors) {
      try {
        my $dbh = $self->_dbh;
        local $dbh->{RaiseError} = 1;
        local $dbh->{PrintError} = 0;
        $dbh->do('SELECT @@IDENTITY');
      } catch {
        $self->throw_exception (
          'Your drivers do not seem to support dynamic cursors (odbc_cursortype => 2).'
         . (
          $self->using_freetds
            ? ' If you are using FreeTDS, make sure to set tds_version to 8.0 or greater.'
            : ''
          )
        );
      };

      $self->_using_dynamic_cursors(1);
      $self->_identity_method('@@identity');
    }
    else {
      $self->_using_dynamic_cursors(0);
      $self->_identity_method(undef);
    }
  }

  $self->next::method (@_);
}


sub connect_call_use_server_cursors {
  my $self            = shift;
  my $sql_rowset_size = shift || 2;

  if ($^O !~ /win32|cygwin/i) {
    $self->throw_exception('Server cursors only work on Windows platforms at '
                          .'the time of writing.');
  }

  $self->_get_dbh->{odbc_SQL_ROWSET_SIZE} = $sql_rowset_size;
}


sub using_freetds {
  my $self = shift;

  my $dsn = $self->_dbi_connect_info->[0];

  $dsn = '' if ref $dsn eq 'CODE';

  return 1 if $dsn =~ /driver=FreeTDS/i
              || ($self->_dbh_get_info(6)||'') =~ /tdsodbc/i;

  return 0;
}

1;


# vim:sw=2 sts=2 et